VBA 배열의 첫 번째 요소 제거

VBA 배열의 첫 번째 요소 제거

다음에서 배열의 첫 번째 요소를 제거하는 방법이 있습니까?VBA?

자바스크립트 같은 것.shift()방법?

Option Explicit

Sub Macro1()

VBA에는 직접적인 방법이 없지만 다음과 같이 첫 번째 요소를 쉽게 제거할 수 있습니다.

'Your existing code
'...
'Remove "ReDim Preserve matriz(1 To UBound(matriz))"
For i = 1 To UBound(matriz)
  matriz(i - 1) = matriz(i)
Next i
ReDim Preserve matriz(UBound(matriz) - 1)

불행히도 없습니다.당신은 그것을 하기 위한 방법을 써야 합니다.한 가지 좋은 예는 http://www.vbforums.com/showthread.php?562928-Remove-Item-from-an-array 입니다.

'~~> Remove an item from an array, then resize the array

    Public Sub DeleteArrayItem(ItemArray As Variant, ByVal ItemElement As Long)
    Dim i As Long

    If Not IsArray(ItemArray) Then
      Err.Raise 13, , "Type Mismatch"
      Exit Sub
    End If

    If ItemElement < LBound(ItemArray) Or ItemElement > UBound(ItemArray) Then
      Err.Raise 9, , "Subscript out of Range"
      Exit Sub
    End If

    For i = ItemElement To lTop - 1
      ItemArray(i) = ItemArray(i + 1)
    Next
    On Error GoTo ErrorHandler:
    ReDim Preserve ItemArray(LBound(ItemArray) To UBound(ItemArray) - 1)
    Exit Sub
    ErrorHandler:
    '~~> An error will occur if array is fixed
    Err.Raise Err.Number, , _
    "Array not resizable."

    End Sub

문자열 배열이 있는 경우 조인, 오프셋 및 다시 분할할 수 있습니다.

Public Sub test()

    Dim vaSplit As Variant
    Dim sTemp As String

    Const sDEL As String = "||"

    vaSplit = Split("1 2 3 4", Space(1))
    sTemp = Join(vaSplit, sDEL)

    vaSplit = Split(Mid$(sTemp, InStr(1, sTemp, sDEL) + Len(sDEL), Len(sTemp)), sDEL)

    Debug.Print Join(vaSplit, vbNewLine)

End Sub

돌아온다

2
3
4

답이 아니라 어레이 어드레싱에 대한 연구입니다.

이 코드: RedDim 보존 matriz(1) matriz(1) = 5

두 개의 요소(0 및 1U Bound()가 1을 반환함)로 배열을 작성합니다.

다음은 이 문제를 탐색하는 데 도움이 될 수 있는 몇 가지 코드입니다.

Option Explicit

Sub Macro1()
   Dim matriz() As Variant
   Dim x As Variant
   Dim i As Integer
   matriz = Array(0)

   ReDim Preserve matriz(1)
   matriz(1) = 5
   ReDim Preserve matriz(2)
   matriz(2) = 10
   ReDim Preserve matriz(3)
   matriz(3) = 4

   Debug.Print "Initial For Each"
   For Each x In matriz
       Debug.Print ":" & x
   Next x
   Debug.Print "Initial For i = 0"
   For i = 0 To UBound(matriz)
       Debug.Print ":" & matriz(i)
   Next i
   Debug.Print "Initial For i = 1"
   For i = 1 To UBound(matriz)
       Debug.Print ":" & matriz(i)
   Next i
   Debug.Print "remove one"

   For i = 1 To UBound(matriz)
     matriz(i - 1) = matriz(i)
   Next i
   ReDim Preserve matriz(UBound(matriz) - 1)

   For Each x In matriz
       Debug.Print ":" & x
   Next x

   Debug.Print "remove one more"
   For i = 1 To UBound(matriz)
     matriz(i - 1) = matriz(i)
   Next i
   ReDim Preserve matriz(UBound(matriz) - 1)

   For Each x In matriz
       Debug.Print ":" & x
   Next x
End Sub

외부:

Initial For Each
:0
:5
:10
:4
Initial For i = 0
:0
:5
:10
:4
Initial For i = 1
:5
:10
:4
remove one
:5
:10
:4
remove one more
:10
:4

직접적인 방법은 없지만 루프가 없는 일종의 작업 :-)

이 접근 방식은 중간 목표 범위를 사용하여

• 어레이 데이터 수신(예: 셀에서 시작)A10) 및
• 크기가 조정된 2차원 데이터 필드로 되돌립니다(셀에서 추출)A11따라서 첫 번째 요소 생략) 및
• 그것을 평평한 1차원 배열로 전치합니다.

예제 코드

Option Explicit

Sub Macro1()
'Method: use temporary target range to restructure array
 Dim matriz() As Variant
 Dim rng      As Range
'[0.1] Assign same data set to array as in original post
 matriz = Array(0, 5, 10, 4)
          Debug.Print "a) original matriz(" & LBound(matriz) & " To " & UBound(matriz) & ")", Join(matriz, ", ")
'instead of:
'  ReDim Preserve matriz(0 To 3)
'  matriz(0) = 0: matriz(1) = 5: matriz(2) = 10: matriz(3) = 4

'[0.2] Set temporary range to memory
 Set rng = ThisWorkbook.Worksheets("Tabelle1").Range("A10").Resize(UBound(matriz) + 1, 1)
'[1] Write array data to range and reassign to matriz cutting first row
 rng = Application.Transpose(matriz)                    ' fill in array data (transposed to column)
 matriz = rng.Offset(1, 0).Resize(UBound(matriz), 1)    ' assign data to (2-dim) array omitting first row
'[2] Transpose back to flat 1-dim array
 matriz = Application.Transpose(Application.Index(matriz, 0, 1))
          Debug.Print "b) ~~>  new matriz(" & LBound(matriz) & " To " & UBound(matriz) & ")", Join(matriz, ", "),

End Sub

VBE의 바로 옆 창에서의 출력 예(Debug.Print)

a) original matriz(0 To 3)  0, 5, 10, 4
b) ~~>  new matriz(1 To 3)  5, 10, 4 

---

//콤보박스 속성 및 메소드를 사용하여 #1 까다로운 대안 편집

Sub RemoveFirstElement()
    'a) Assign same data set to array as in original post
    Dim matriz() As Variant
    matriz = Array(0, 5, 10, 4)
        Debug.Print "a) original matriz (" & LBound(matriz) & " To " & UBound(matriz) & ")", Join(matriz, ", ")
    'b) Remove first element in matriz (note 0-based indices!)
    RemoveElem matriz, 0             ' << call help procedure RemoveElem
        Debug.Print "b) ~~>  new matriz (" & LBound(matriz) & " To " & UBound(matriz) & ")", Join(matriz, ", ")
End Sub

도움말 절차RemoveElem

이 도움말 절차는 통합 방법을 통해 이익을 얻습니다..RemoveItem추가 사용자 양식을 작성할 필요 없이 즉시 사용할 수 있는 콤보 상자 컨트롤 *)

Sub RemoveElem(arr, ByVal elemIndex As Long)
    'Use combobox properties and methods on the fly (without need to create form)
    With CreateObject("Forms.ComboBox.1")
        'a) assign existing values
        .List = Application.Transpose(arr)
        'b) delete e.g. 1st element (0-based control indices!)
        .RemoveItem elemIndex
        'c) assign modified values to tmp array (losing 2nd dimension by transposition)
        Dim tmp As Variant
        tmp = Application.Transpose(.List)
        'd) decrement base by 1 (from 1 to 0) - optional
        ReDim Preserve tmp(0 To UBound(tmp) - 1)
        'e) overwrite original array
        arr = tmp
    End With
End Sub

VBE의 바로 옆 창에서의 출력 예(Debug.Print)

a) original matriz(0 To 3)  0, 5, 10, 4
b) ~~>  new matriz(1 To 3)  5, 10, 4 

관련 링크

다음에서 0 기반 배열을 반환할 수 있습니까?ws.UsedRange?

*)Create an empty 2d-array)에서 솔로 콤보 상자를 만드는 방법을 찾았습니다.

다음은 JS의 시프트 방법과 같이 동작하는 함수 "Shift"와 "Shift"의 사용 예입니다.

Sub tryShift()

Dim aRy As Variant, sT As Variant

aRy = Array("one", "two", "three", "four")

Debug.Print "Original array:"
For Each sT In aRy
Debug.Print sT
Next

aRy = Shift(aRy)

Debug.Print vbCrLf & "Array having been " & Chr(34) & "shifted" & Chr(34) & ":"
For Each sT In aRy
Debug.Print sT
Next

End Sub

Function Shift(aRy As Variant)

Dim iCt As Integer, iUbd As Integer

iCt = 0
iUbd = UBound(aRy)

Do While iCt < iUbd
    aRy(iCt) = aRy(iCt + 1)
    iCt = iCt + 1
Loop

ReDim Preserve aRy(UBound(aRy) - 1)

Shift = aRy

End Function

출력:

Original array:
one
two
three
four

Array having been "shifted":
two
three
four

언급URL : https://stackoverflow.com/questions/34231734/remove-the-first-element-of-a-vba-array